/* <Created>#12/10/2009 12:26:13#</Created> */
/* <Goal>Main definitions of variables for different English periods</Goal> */
/* <Comment>Basic definitions for OE, ME, eModE and LmodE work with CorpusSearch II

History:
21/sep/2011	ERK	Added "nosubject"</Comment> */
// --------------------------------------------------------------------
// Name:	OE+MEU.def
// Goal:	Combined definitions for OE and ME processing
// Note:	the possessive pronouns (PRO$) are excluded from the
//		  third person pronoun list
// History:
// 10-07-2009	ERK	Combined from Ans van Kemenade
// 21-07-2009	ERK	Added personal pronoun section for ICHL19
// 22-07-2009	ERK	Added more NP definitions (timenp, object etc)
// 19-10-2009	ERK	Changed NOUN definition from N* into N-*
// 18-12-2009 ERK	Added definition of "contrast"
// --------------------------------------------------------------------

// ----------------------------------------------------------------------------------------
// Definitions of different IP categories
// ----------------------------------------------------------------------------------------
finiteIP: IP-MAT*|IP-SUB*
matrixIP: IP-MAT*
subIP:    IP-SUB*
anyCP:    CP|CP-*
badCP:    CP-QUE*|CP-ADV*
anyXP:    *P-*|*P
negation: NEG-*|NEG

// ----------------------------------------------------------------------------------------
// Definitions of coreferencing
// ----------------------------------------------------------------------------------------
IsRefer:  Identity|CrossSpeech|Inferred
NoRefer:  Assumed|New*
AnyNoRef: Assumed|New*|Inert
IsNew:    New
IsInert: Inert

// ----------------------------------------------------------------------------------------
// Definitions of verbal categories
// ----------------------------------------------------------------------------------------
finiteaux: BEI|BEP*|BED*|UTP|*HVI|*HVP*|*HVD*|*AXI|*AXP*|*AXD*|*MD|*DOI|*DOP*|*DOD*|NEG+BEI|NEG+BEP*|NEG+BED*|NEG+AXI|NEG+*AXP*|NEG+*AXD*|NEG+*MD
nonfiniteverb: *BE|*BAG*|*BEN*|*HV|*HVG*|*HVN*|*AX|*AXG*|*AXN*|*VB|*VAG*|*VAN*|VBN*|VBG*|HAN*|HAG*
unonfiniteverb: BE|BAG*|BEN*|U-BE|U-BAG*|U-BEN*|U-VB|U-VAG*|U-VAN*|U-VBN*|U-VBG*
finiteverb: BEI|BEP*|BED*|UTP|*HVI|*HVP*|*HVD*|*AXI|*AXP*|*AXD*|*MD|VBI|*VBP*|*VBD*|*DOI|*DOP*|*DOD*|NEG+BEI|NEG+BEP*|NEG+BED*|NEG+AXI|NEG+*AXP*|NEG+*AXD*|NEG+*MD|NEG+VBI|NEG+*VBP*|NEG+*VBD
ufiniteverb: BEI|BEP*|BED*|U-BEI|U-BEP*|U-BED*|U-VBI*|U-VBP*|U-VBD*|NEG+BEI|NEG+BEP*|NEG+BED*
accfiniteverb: UTP|*HVI|*HVP*|*HVD*|*AXI|*AXP*|*AXD*|*MD|VBI|*VBP*|*VBD*|*DOI|*DOP*|*DOD*|NEG+AXI|NEG+*AXP*|NEG+*AXD*|NEG+*MD|NEG+VBI|NEG+*VBP*|NEG+*VBD
unaccfiniteverb:BEI|BEP*|BED*|NEG+BEI|NEG+BEP*|NEG+BED*
finite_BE: BEP*|BED*|NEG+BEP*|NEG+BED*
progressive: *ing*|*yng*

// ----------------------------------------------------------------------------------------
// Definitions of different AP categories
// ----------------------------------------------------------------------------------------
anypp: PP|PP-*
someap: ADVP-*|ADJP*
timeap: ADVP-TMP*
then_word: then|+ten|+ta|+tonne|than
advsent: ADVP*|ALSO

// ----------------------------------------------------------------------------------------
// Definitions of different NP categories
// ----------------------------------------------------------------------------------------
subjectoe:  NP-NOM|NP-NOM-#|NP-NOM-RSP
subject:    $subjectoe|NP-SBJ*
badsubject: EX
nosubject:  *PRD*|*LFD*|*VOC*|*MSR*|*TMP*
noobject:   *PRD*|*LFD*|*VOC*|*MSR*|*ADV*|*TMP*
timenp:     NP*TMP
anynp:      NP|NP-*
nonPrnNp:   NP|NP-[A-OQ-Z]*
leftdisnp:  NP-*LFD*
resumpnp:   NP-*RSP*
posspro:    PRO$|PRO$^*
// ----------------------------------------------------------------------------------------
// The following definition of an object NP excludes e.g. NP-DAT-TMP, NP-GEN-TMP from the list
//  (ranges do not seem to work)
// ----------------------------------------------------------------------------------------
// objectonly: NP-OB*|NP-DAT|NP-DAT-[A-SU-Z]*|NP-GEN|NP-GEN-[A-SU-Z]*|NP-ACC|NP-ACC-[A-SU-Z]*
objectonly:   NP-OB*|NP-DAT*|NP-GEN*|NP-ACC*
object:       $objectonly|$subjectoe|$timenp
objectnotime: $objectonly|$subjectoe
objectorpp:   $object|PP-*

// ----------------------------------------------------------------------------------------
// Definitions of contents of NPs
// ----------------------------------------------------------------------------------------
noun: N-*|NR*|FW|*Q*|D*
dem: D^*|D-*|D
pronoun: PRO^N|PRO^A|PRO^G|PRO^D|PRO|DPRO^N|DPRO^A|DPRO^G|DPRO^D|PRO-*
nonpronominal: D*|ADJ*|N*|*Q*|NUM*|FP|FW|CP*|PTP*|V*|RP+V*|CONJ*

// pronoun_2p_ME=+ge|+gee|+geu|+gew||gho|+gie
// pronoun_2s_ME=+de|+die|+du
// pronoun_3s_ME=+git|+gitt
// pronoun_2c_ME=+gou|+goug|+gow

// -------------------------------------------------------------------
// Third person singular, masculine
//	N.B: [him] can be both 3p as well as OE 3ms
// -------------------------------------------------------------------
pronoun_3ms: ha|ham|he|hee|hy~|hym|hyne|hine|him|ham-seolf|ham-seolfen|ham-seolue|ham-seoluen|him-seolf|him-seoluen|hymself|hymselfe
// -------------------------------------------------------------------
// Third person singular, feminine
// -------------------------------------------------------------------
pronoun_3fs: heo|hir|sche|she|her|hi|hie|hire|hig|hio|hiere|hyre|hier-seolf|hier-seoluen
// -------------------------------------------------------------------
// Third person singular, neuter
// -------------------------------------------------------------------
pronoun_3ns: [Yy]t|[Yy]=t=|[Yy]tt|[Ii]t|$[Ii]t|[Ii]d|[Ii]tt|'[tT]|$'[tT]|[Hh]it|[Hh]yt|[Hh]ytt|[Hh]vt
// -------------------------------------------------------------------
// Third person plural
//	N.B: [him] can be both 3p as well as OE 3ms
// -------------------------------------------------------------------
pronoun_3p: hem|tey|+tei|thei|them|they|+tey|+tey+g|+theym|heom|him|themselfe|hemself
// -------------------------------------------------------------------
// Combine all different 3rd person pronouns into one category
// -------------------------------------------------------------------
pronoun_3: $pronoun_3ms|$pronoun_3fs|$pronoun_3ns|$pronoun_3p
// -------------------------------------------------------------------
// Define pronouns that are very unlikely to be referential: it, hit
// -------------------------------------------------------------------
pronoun_it: [Yy]t|[Yy]=t=|[Yy]tt|[Ii]t|$[Ii]t|[Ii]d|[Ii]tt|'[tT]|$'[tT]|[Hh]it|[Hh]yt|[Hh]ytt|[Hh]vt
pronoun_that: that|tht|+tat|+tt|$that


// -------------------------------------------------------------------
// Definitions of conjunction types
// -------------------------------------------------------------------
contrast: but|ac

// -------------------------------------------------------------------
// Default values for ignore_nodes and ignore_words
// -------------------------------------------------------------------
// ignore_nodes: COMMENT|CODE|ID|LB|'|\"|,|E_S|.|/|RMV:*
// ignore_words: COMMENT|CODE|ID|LB|'|\"|,|E_S|.|/|RMV:*|0|\**
// -------------------------------------------------------------------

